USE [master]
GO
/****** Object: StoredProcedure [dbo].[sp_help_revlogin] Script Date: 06/02/2010 11:25:50 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
IF OBJECT_ID('[dbo].[sp_help_revlogin]') IS NOT NULL DROP PROCEDURE [dbo].[sp_help_revlogin]
GO
CREATE PROCEDURE [dbo].[sp_help_revlogin] @login_name SYSNAME = NULL
AS
DECLARE @name SYSNAME
DECLARE @type VARCHAR (1)
DECLARE @hasaccess INT
DECLARE @denylogin INT
DECLARE @is_disabled INT
DECLARE @PWD_varbinary VARBINARY (256)
DECLARE @PWD_string VARCHAR (514)
DECLARE @SID_varbinary VARBINARY (85)
DECLARE @SID_string VARCHAR (514)
DECLARE @tmpstr VARCHAR (1024)
DECLARE @is_policy_checked VARCHAR (3)
DECLARE @is_expiration_checked VARCHAR (3)
DECLARE @role_bulkadmin VARCHAR (1)
DECLARE @role_dbcreator VARCHAR (1)
DECLARE @role_diskadmin VARCHAR (1)
DECLARE @role_processadmin VARCHAR (1)
DECLARE @role_securityadmin VARCHAR (1)
DECLARE @role_serveradmin VARCHAR (1)
DECLARE @role_setupadmin VARCHAR (1)
DECLARE @role_sysadmin VARCHAR (1)
DECLARE @defaultdb SYSNAME
IF (@login_name IS NULL)
DECLARE login_curs CURSOR FOR
SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin,
l.bulkadmin,l.dbcreator,l.diskadmin,l.processadmin,l.securityadmin,l.serveradmin,l.setupadmin,l.sysadmin
FROM sys.server_principals p LEFT JOIN sys.syslogins l
ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name <> 'sa'
ELSE
DECLARE login_curs CURSOR FOR
SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin,
l.bulkadmin,l.dbcreator,l.diskadmin,l.processadmin,l.securityadmin,l.serveradmin,l.setupadmin,l.sysadmin
FROM
sys.server_principals p LEFT JOIN sys.syslogins l
ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name = @login_name
OPEN login_curs
FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin,@role_bulkadmin,@role_dbcreator,@role_diskadmin,@role_processadmin,@role_securityadmin,@role_serveradmin,@role_setupadmin,@role_sysadmin
IF (@@FETCH_STATUS = -1)
BEGIN
PRINT 'No login(s) found.'
CLOSE login_curs
DEALLOCATE login_curs
RETURN -1
END
SET @tmpstr = '/* sp_help_revlogin script '
PRINT @tmpstr
SET @tmpstr = '** Generated ' + CONVERT (VARCHAR, GETDATE()) + ' on ' + @@SERVERNAME + ' */'
PRINT @tmpstr
PRINT ''
WHILE (@@FETCH_STATUS <> -1)
BEGIN
IF (@@FETCH_STATUS <> -2)
BEGIN
PRINT ''
SET @tmpstr = '-- Login: ' + @name
PRINT @tmpstr
IF (@type IN ( 'G', 'U'))
BEGIN -- NT authenticated account/group
SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' FROM WINDOWS WITH DEFAULT_DATABASE = [' + @defaultdb + ']'
END
ELSE BEGIN -- SQL Server authentication
-- obtain password and sid
SET @PWD_varbinary = CAST( LOGINPROPERTY( @name, 'PasswordHash' ) AS VARBINARY (256) )
EXEC sp_hexadecimal @PWD_varbinary, @PWD_string OUT
EXEC sp_hexadecimal @SID_varbinary,@SID_string OUT
-- obtain password policy state
SELECT @is_policy_checked = CASE is_policy_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name
SELECT @is_expiration_checked = CASE is_expiration_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name
SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' WITH PASSWORD = ' + @PWD_string + ' HASHED, SID = ' + @SID_string + ', DEFAULT_DATABASE = [' + @defaultdb + ']'
IF ( @is_policy_checked IS NOT NULL )
BEGIN
SET @tmpstr = @tmpstr + ', CHECK_POLICY = ' + @is_policy_checked
END
IF ( @is_expiration_checked IS NOT NULL )
BEGIN
SET @tmpstr = @tmpstr + ', CHECK_EXPIRATION = ' + @is_expiration_checked
END
END
IF (@denylogin = 1)
BEGIN -- login is denied access
SET @tmpstr = @tmpstr + '; DENY CONNECT SQL TO ' + QUOTENAME( @name )
END
ELSE IF (@hasaccess = 0)
BEGIN -- login exists but does not have access
SET @tmpstr = @tmpstr + '; REVOKE CONNECT SQL TO ' + QUOTENAME( @name )
END
IF (@is_disabled = 1)
BEGIN -- login is disabled
SET @tmpstr = @tmpstr + '; ALTER LOGIN ' + QUOTENAME( @name ) + ' DISABLE'
END
PRINT @tmpstr
END
SET @tmpstr = ''
If @role_bulkadmin = '1'
BEGIN
SET @tmpstr = 'EXEC master..sp_addsrvrolemember @loginame = N''' + @name + ''' , @rolename = N''bulkadmin'' '
END
IF @role_dbcreator = '1'
BEGIN
SET @tmpstr = 'EXEC master..sp_addsrvrolemember @loginame = N''' + @name + ''' , @rolename = N''dbcreator'' '
END
IF @role_diskadmin = '1'
BEGIN
SET @tmpstr = 'EXEC master..sp_addsrvrolemember @loginame = N''' + @name + ''' , @rolename = N''diskadmin'' '
END
IF @role_processadmin = '1'
BEGIN
SET @tmpstr = 'EXEC master..sp_addsrvrolemember @loginame = N''' + @name + ''' , @rolename = N''processadmin'' '
END
IF @role_securityadmin = '1'
BEGIN
SET @tmpstr = 'EXEC master..sp_addsrvrolemember @loginame = N''' + @name + ''' , @rolename = N''securityadmin'' '
END
IF @role_serveradmin = '1'
BEGIN
SET @tmpstr = 'EXEC master..sp_addsrvrolemember @loginame = N''' + @name + ''' , @rolename = N''serveradmin'' '
END
IF @role_setupadmin = '1'
BEGIN
SET @tmpstr = 'EXEC master..sp_addsrvrolemember @loginame = N''' + @name + ''' , @rolename = N''setupadmin'' '
END
IF @role_sysadmin = '1'
BEGIN
SET @tmpstr = 'EXEC master..sp_addsrvrolemember @loginame = N''' + @name + ''' , @rolename = N''sysadmin'' '
END
IF @tmpstr <> ''
PRINT @tmpstr
FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin,@role_bulkadmin,@role_dbcreator,@role_diskadmin,@role_processadmin,@role_securityadmin,@role_serveradmin,@role_setupadmin,@role_sysadmin
END
CLOSE login_curs
DEALLOCATE login_curs
RETURN 0
GO
/****** Object: StoredProcedure [dbo].[sp_hexadecimal] Script Date: 06/02/2010 11:25:51 ******/
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
IF OBJECT_ID('[dbo].[sp_hexadecimal]') IS NOT NULL DROP PROCEDURE [dbo].[sp_hexadecimal]
GO
CREATE PROCEDURE [dbo].[sp_hexadecimal]
@binvalue VARBINARY(256),
@hexvalue VARCHAR (514) OUTPUT
AS
DECLARE @charvalue VARCHAR (514)
DECLARE @i INT
DECLARE @length INT
DECLARE @hexstring CHAR(16)
SELECT @charvalue = '0x'
SELECT @i = 1
SELECT @length = DATALENGTH (@binvalue)
SELECT @hexstring = '0123456789ABCDEF'
WHILE (@i <= @length)
BEGIN
DECLARE @tempint INT
DECLARE @firstint INT
DECLARE @secondint INT
SELECT @tempint = CONVERT(INT, SUBSTRING(@binvalue,@i,1))
SELECT @firstint = FLOOR(@tempint/16)
SELECT @secondint = @tempint - (@firstint*16)
SELECT @charvalue = @charvalue +
SUBSTRING(@hexstring, @firstint+1, 1) +
SUBSTRING(@hexstring, @secondint+1, 1)
SELECT @i = @i + 1
END
SELECT @hexvalue = @charvalue
GO